filename datoteka temp;
proc http
 url="http://www.efzg.hr/userdocsimages/sta/jarneric/BAZA.xlsx"
 method="GET"
 out=datoteka;
run;
proc import datafile=datoteka out=WORK.moji_podaci dbms=xlsx replace;
  sheet="AAPL";
  getnames=YES;
run;

proc univariate data=moji_podaci;
var close;
title "Deskriptivna statistika zakljucnih cijena";
run;

proc format;
value close 130-140="130-140"
			140-150="140-150"
			150-160="150-160"
			160-170="160-170"
			170-180="170-180";
proc freq data=moji_podaci;
tables close;
format close close.;
title "Distribucija frekvencija zakljucnih cijena";
run;

proc sgplot data=moji_podaci;
histogram close / binstart=135 nbins=5;
density close / type=normal;
run;

proc sgplot data=moji_podaci;
hbox close / extreme;
title "B-P dijagram";
run;

proc ttest data=moji_podaci h0=155.47 sides=2 alpha=0.05 plots=none;
var close;
title "Dvosmjerni test hipoteze o pretpostavljenoj vrijednosti sredine populacije";
run;

proc ttest data=moji_podaci h0=155.47 sides=u alpha=0.02 plots=none;
var close;
title "Jednosmjerni test hipoteze o pretpostavljenoj vrijednosti sredine populacije";
run;

proc corr data=moji_podaci;
var close high;
title "Korelacijska matrica";
run;

proc sgplot data=moji_podaci;
reg x=close y=high / degree=1;
title "Dijagram rasipanja i regresijski pravac";
run;

proc reg data=moji_podaci plots=none;
model close=high low / clb alpha=0.05;
title "Multipla regresija";
run;